法師競技場專用宏

由 hepha 於 週二 12月 25, 2007 10:25 pm

技能有的要自已修改成正確名稱，我是直接從ngacn大陸論壇用軟體翻成中文，大陸用語有的跟台灣用語不同 (d8) ，不改的話巨集會施效
作者：柳三公子
法師競技場專用宏，重新編輯過了，求精
昨天離線寫了幾個宏，回家後發現漏洞百出，現在重新貼出我自己使用全部宏，求加精
使用以下宏之前，請確認你有下列插件：FocusFrame,NECB(推薦，可選),Quartz(推薦，可選)
智能變羊宏

代碼: 全部選取

#showtooltip 變形術
/Cast [target=focus,harm,exists,modifier:shift]變形術; [target=mouseover, harm, exists]變形術; 變形術
/focus [target=focus,noexists] [target=focus,dead] target  

功能：按shift，並且當前已經設置的焦點目標，則強制把你的焦點目標變羊。如果沒按shift，並且你的鼠標當前指向敵對目標，則將你鼠標指向的目標變羊，否則將你當前目標變羊。如果你之前沒有設置焦點目標，或者焦點目標已經死亡，則將你當前目標設置為焦點目標。目前還在打副本，所以用了高級羊，如果只打競技場，請用1級羊省藍，在競技場裡面，1級和高級效果是一樣的。
強化反制宏

代碼: 全部選取

#showtooltip 法術反制
/stopcasting
/cancelaura 寒冰屏障
/Cast [target=focus,harm,exists,modifier:shift]法術反制; [target=mouseover, harm, exists]法術反制; 法術反制
/focus [target=focus,noexists] [target=focus,dead] target

功能：這個宏我自己覺得我寫得比較牛，首先會自動打斷自己的當前施法，如果在冰箱裡面的話，會自動出冰箱。然後如果按了Shift，就反制焦點，沒按Shift就反制鼠標指向的目標，如果鼠標沒有指向目標，就反制當前目標。
機關槍宏

代碼: 全部選取

/stopcasting
/cast [target=風怒圖騰, harm, exists] 冰槍術
/cast [target=顫慄圖騰, harm, exists] 冰槍術
/cast [target=地縛圖騰, harm, exists] 冰槍術
/cast [target=法力之泉圖騰, harm, exists] 冰槍術
/cast [target=法力之潮圖騰, harm, exists] 冰槍術
/cast [target=根基圖騰, harm, exists] 冰槍術
/cast [target=清毒圖騰, harm, exists] 冰槍術
/cast [target=灼熱圖騰, harm, exists] 冰槍術
/cast [target=mouseover,harm,exists]冰槍術;冰槍術

功能：自動打圖騰，沒有指定圖騰，就打鼠標指向目標，也沒有的話就打當前目標。不會改變當前目標，需要打其他圖騰的自己加
一鍵水元素
沒水元素就召喚，有了水元素就放遠程冰環

代碼: 全部選取

#showtooltip [pet] 冰凍術; [nopet] 召喚水元素
/cast [nopet] 召喚水元素
/click [pet] PetActionButton5  

配合上面的宏，有了這個：急冷之前解散水元素

代碼: 全部選取

/script PetDismiss();
/cast 急速冷卻

智能冰甲

代碼: 全部選取

/cast [combat]冰甲術(等級 1);冰甲術

戰鬥外補頂級冰甲，戰鬥中補1級冰甲，競技場裡面被集火的時候，多一個buff也是多一份存活的希望，所以需要補冰甲，但是為了省藍，所以補1級最合算。1級冰甲少300多護甲，但是附帶的減速和刺骨效果是很重要的。
超級冰箭宏

代碼: 全部選取

#showtooltip [modifier:alt]寒冰箭(等級 1);寒冰箭
/Cast [target=mouseover, harm, exists,modifier:alt]寒冰箭(等級 1);[modifier:alt]寒冰箭(等級 1)
/stopmacro [modifier:alt]
/Cast [target=mouseover, harm, exists]寒冰箭;寒冰箭

直接按，頂級冰箭，按了alt，就是1級冰箭，並且優先攻擊鼠標指向目標，指哪打哪，堪比六脈神劍
另一個冰箭宏，很多人說更靈活

代碼: 全部選取

#showtooltip [modifier:alt]寒冰箭(等級 1);寒冰箭
/cast [modifier:alt][target=mouseover, harm, exists]寒冰箭(等級 1);寒冰箭

鼠標指向的目標永遠用1級的，按了alt就是強制1級的，其他情況用頂級。
奧爆炸賊宏

代碼: 全部選取

#showtooltip 魔爆術
/cast [noharm] 魔爆術(等級 1);魔爆術

有敵對目標頂級爆，沒有目標1級爆，就是針對賊突然消失讓你失去目標的時候可以省藍。
吃喝相關

代碼: 全部選取

/cast [modifier:alt] 造水術
/use [nomodifier:alt] 魔法山泉水

按alt造水，直接按就是喝水，面包同理，可以自己修改，我就不寫了
解詛咒

代碼: 全部選取

/cast [target=party1] 解除次級詛咒

幫自己第一個隊友解詛咒，party1里面的1可以用2-4替換，我一共寫了4個宏，分別設定快捷鍵從F2-F5，而解自己用F1，不需要宏，但是需要打開界面設置裡的自動自我施法，我強烈建議所有法師都打開這個選項，沒有壞處的。
魔法石

代碼: 全部選取

/castsequence reset=120 製造魔法玉石, 製造魔法紅寶石


吃石頭

代碼: 全部選取

/use 法力剛玉
/use 法力紅寶石

以上兩個不用解釋了，我習慣把兩個宏分開，大家也可以參照其他宏教程把2個宏合併，不過合併會造成一些問題，我個人不提倡。
最後是一些通用宏
坐騎

代碼: 全部選取

#showtooltip [flyable]迅捷紅色馭風者;[noflyable] 黑色軍用迅猛龍哨
/use [nomounted, flyable] 迅捷紅色馭風者
/castrandom [nomounted, noflyable] 紫色骷髏戰馬, 黑色軍用迅猛龍哨, 霜狼嗥叫者的號角
/dismount [mounted]

在外域自動騎鳥，在舊大陸隨機從多個坐騎裡面選一個騎，已經騎乘的時候直接下馬，速度非常快。
繃帶宏

代碼: 全部選取

/use 戰歌峽谷符文布繃帶
/use 奧特蘭克厚符文布繃帶
/use 阿拉希盆地符文布繃帶
/use 厚靈紋布繃帶

自動根據所在戰場使用對應的繃帶，不在戰場就用普通繃帶
吃紅

代碼: 全部選取

/use 極效治療石
/use 特效治療藥水
/use 不穩定的治療藥水
/use 特效作戰治療藥水
/use 食人魔特釀紅酒

吃藍

代碼: 全部選取

/use 特傚法力藥水
/use 特效作戰法力藥水
/use 不穩定的法力藥水
/use 食人魔特釀藍酒